這兩天看到有朋友問起Html內的各種控件怎麼用script進行操作，現在自己也總結一下。因為項目原因，很多程序都是用VBScript寫的，感興趣的朋友可以改寫成JavaScript，到時候別忘了共享一下啊，活活。
OK，切入主題，現介紹一下：
今天介紹使用VBScript判斷復選框的選中數量和被選中的復選框的值。
在生成某個一覽表時，比如一個訂貨單一覽表，每條訂貨單記錄前面可能會放置一個復選框，以提供批量刪除，發行等功能。一般每個復選框的值也就是後面對應記錄的主鍵的值，如訂貨單編號。在執行刪除、發行等功能時，就要知道選了幾個復選框，這些復選框分別對應什麼值，下面就說一下方法。
程序分為三部分：
一、判斷被選定的CheckBox是一個還是一個以上
主要思路是：當有多個同名的復選框，但ID不同時，舉例復選框控件名為chkTest，那麼它將被以數組的形式調用，比如說有三個復選框名字叫chkTest，ID分別是chkTest1,chkTest2,chkTest3，那麼要想查看三個復選框的checked屬性就要這麼寫：chkTest(0).checked, chkTest(1).checked, chkTest(2).checked (數組從零開始)；而當只有一個復選框的時候，直接可以使用chkTest.checked。這樣就決定了對於數量不同的（1個或多個兩種分別），只能采用不同的方法來取得復選框的信息。由於當有多個同名不同ID的控件時，該控件擁有“控件名.type”這個屬性，而這個只讀的屬性可以等於任何字符串，也就是說 控件名.type = “任意字符串“ 恆為true。當然，這只是對有控件名.type這個屬性的時候，否則恆為false，這樣也就分辨出在一覽表裡的復選框是單個還是多個了。程序如下：
'*************************************************
'<函數名>
' gfIs_ArrayTest(obj)
'<功能>
' 判斷選定的CheckBox的是一個還是一個以上
'<參數>
' CheckBox對象名
'<返回值>
' true
' false
'<備注>
' Created on Mar.15th.2004 by AITD
'*************************************************
function gfIs_ArrayTest(obj)
on error resume next
if obj.type = "flag" then
gfIs_ArrayTest = True
else
gfIs_ArrayTest = False
end if
end function
二、檢查畫面上復選框的選擇是否符合要求
所謂是否符合要求的意思就是，比如說，刪除的時候選擇起碼一條記錄，修正的時候選且只能選擇一條記錄，至於其他的，什麼只能選擇5條，只能選擇10條等等，下面的程序改以下就行了。別忘了剛才說的，只有一個復選框和有多個復選框的處理方法是不一樣的。
'******************************************************
'<函數名>
' gfChkCheckbox()
'<功能>
' 檢查畫面CheckBox的選擇是否符合要求
'<參數>
' obj: 對應的checkbox控件
' flag: 檢查規則：0 可有多個被選中
' 1 只能有一個被選中
' name: 提示用戶那個控件報錯的信息
'<返回值>
' true
' false
'<備注>
' Created on Mar.15th.2004 by AITD
'******************************************************
function gfChkCheckbox(obj,flag,name)
Dim i
Dim j
gfChkCheckbox = false
i = 0
j = 0
'若對象不存在
if isnull(obj) then
msgbox "請選擇一個 " + name + "。" '請選擇一個對象
gfChkCheckbox = false
exit function
end if
'對象只有一個
if not gfIs_ArrayTest(obj) then
if obj.checked = false then
msgbox "請選擇一個 " + name + "。" '請選擇一個對象
gfChkCheckbox = false
exit function
else
gfChkCheckbox = true
exit function
end if
end if
'若有多個對象存在
for i = 0 to (obj.length - 1)
if obj(i).type = "checkbox" then
if obj(i).checked = true then
j = j + 1
end if
end if
next
if j = 0 then
msgbox "請選擇 " + name + "。" '請選擇一個對象
gfChkCheckbox = false
exit function
end if
if j = 1 then
gfChkCheckbox = true
exit function
end if
if j > 1 then
if flag = 1 then
msgbox "只能選擇一個 " + name + "。" '只能選擇一個對象
gfChkCheckbox = false
exit function
else
gfChkCheckbox = true
exit function
end if
end if
end function
三、取得復選框的值
為了後面處理的方便，常把重要的信息保存在復選框的value屬性裡，以便後面取用。下面的程序將選中的復選框的值以間隔符 “^|^“ 串成一個字符串並返回。
'*************************************************
'<函數名>
' gfGetCheckBoxValue(obj)
'<功能>
' 取得選定的CheckBox的值
'<參數>
' CheckBox對象名
'<返回值>
' 選定的CheckBox的值
'<備注>
' Created on Mar.15th.2004 by AITD
'*************************************************
function gfGetCheckBoxValue(obj)
dim strValue
dim intCounter
dim i
strValue = ""
intCounter = 0
'如果對象不存在
if isnull(obj) then
gfGetCheckBoxValue = strValue
exit function
end if
'如果對象為一個
if not gfIs_ArrayTest(obj) then
if obj.checked = false then
gfGetCheckBoxValue = strValue
exit function
else
gfGetCheckBoxValue = obj.value
exit function
end if
end if
'如果對象為多個
for i = 0 to obj.length - 1
if obj(i).checked = true then
if intCounter > 0 then
strValue = strValue & "^|^" & CStr(obj(i).value)
else
strValue = CStr(obj(i).value)
end if
intCounter = intCounter + 1
end if
next
gfGetCheckBoxValue = strValue
end function
上面就是VBScript裡面處理復選框的方法（偶用的）。可以把這幾個函數封裝到一個共通的vbs文件中，並在Html的<head>標記區內引用就可以通用了~ 如 <head><script language=vbscript src=vbsChkBoxTool.vbs></script></head>
還要注意一個問題，在實際應用中,有可能根據查詢條件生成的一覽表裡一條記錄也沒有，就是說沒有復選框控件，如果仍舊調用這樣一個名字的控件，這時候IE就會報錯。沒有什麼太好的解決辦法，於是寫了一段程序繞過這個沒有復選框控件的情況：
function sIsChkBoxExist()
on error resume next
err.clear
if isEmpty(document.frmOrderList.chkOrder) then
end if
if err.number <> 0 then
else
sIsChkBoxExist=true
end if
err.clear
end function
程序中對預定的控件隨便做一個操作，如isEmpty，如果捕捉到了err.number>0的情況，就說明該控件不存在，但由於有on error resume next，所以不會提示錯誤，這樣也就判斷出了控件存不存在。
每次在調用上面三個函數之前，先調用一次sIsChkBoxExist函數，看看對應的控件存不存在，這樣就不會有錯了。
