oracle存儲過程常用的技巧（詳），oracle存儲過程技巧

oracle存儲過程常用的技巧（詳），oracle存儲過程技巧

我們在進行pl/sql編程時打交道最多的就是存儲過程了。存儲過程的結構是非常的簡單的，我們在這裡除了學習存儲過程的基本結構外，還會學習編寫存儲過程時相關的一些實用的知識。如：游標的處理，異常的處理，集合的選擇等等

1.存儲過程結構

1.1 第一個存儲過程

create or replace procedure proc1(  
 p_para1 varchar2,  
 p_para2 out varchar2,  
 p_para3 in out varchar2  
)as  
 v_name varchar2(20);  
begin  
 v_name := '張三豐';  
 p_para3 := v_name;  
 dbms_output.put_line('p_para3:'||p_para3);  
end; 

上面就是一個最簡單的存儲過程。一個存儲過程大體分為這麼幾個部分:

創建語句：create or replace procedure 存儲過程名

如果沒有or replace語句，則僅僅是新建一個存儲過程。如果系統存在該存儲過程，則會報錯。Create or replace procedure 如果系統中沒有此存儲過程就新建一個，如果系統中有此存儲過程則把原來刪除掉，重新創建一個存儲過程。

存儲過程名定義：包括存儲過程名和參數列表。參數名和參數類型。參數名不能重復， 參數傳遞方式:IN, OUT, IN OUT

IN 表示輸入參數，按值傳遞方式。

OUT 表示輸出參數，可以理解為按引用傳遞方式。可以作為存儲過程的輸出結果，供外部調用者使用。

IN OUT 即可作輸入參數，也可作輸出參數。

參數的數據類型只需要指明類型名即可，不需要指定寬度。

參數的寬度由外部調用者決定。
過程可以有參數，也可以沒有參數

變量聲明塊：緊跟著的as (is )關鍵字，可以理解為pl/sql的declare關鍵字，用於聲明變量。

變量聲明塊用於聲明該存儲過程需要用到的變量，它的作用域為該存儲過程。另外這裡聲明的變量必須指定寬度。遵循PL/SQL的變量聲明規范。

過程語句塊：從begin 關鍵字開始為過程的語句塊。存儲過程的具體邏輯在這裡來實現。

異常處理塊：關鍵字為exception ，為處理語句產生的異常。該部分為可選

結束塊：由end關鍵字結果。

1.2 存儲過程的參數傳遞方式

存儲過程的參數傳遞有三種方式:IN,OUT,IN OUT .

IN 按值傳遞，並且它不允許在存儲過程中被重新賦值。如果存儲過程的參數沒有指定存參數傳遞類型，默認為IN

create or replace procedure proc1(  
 p_para1 varchar2,  
 p_para2 out varchar2,  
 p_para3 in out varchar2  
)as  
 v_name varchar2(20);  
begin  
 p_para1 :='aaa';  
 p_para2 :='bbb';  
 v_name := '張三豐';  
 p_para3 := v_name;  
 dbms_output.put_line('p_para3:'||p_para3);  
 null;  
end;  
    
Warning: Procedure created with compilation errors  
 
SQL> show error;  
Errors for PROCEDURE LIFEMAN.PROC1:  
 
LINE/COL ERROR  
-------- ----------------------------------------------------------------------  
8/3   PLS-00363: expression 'P_PARA1' cannot be used as an assignment target  
8/3   PL/SQL: Statement ignored 

這一點與其它高級語言都不同。它相當於java在參數前面加上final關鍵字。

OUT 參數：作為輸出參數，需要注意，當一個參數被指定為OUT類型時，就算在調用存儲過程之前對該參數進行了賦值，在存儲過程中該參數的值仍然是null.

create or replace procedure proc1(  
 p_para1 varchar2,  
 p_para2 out varchar2,  
 p_para3 in out varchar2  
)as  
 v_name varchar2(20);  
begin  
 v_name := '張三豐';  
 p_para3 := v_name;  
 dbms_output.put_line('p_para1:'||p_para1);  
 dbms_output.put_line('p_para2:'||p_para2);  
 dbms_output.put_line('p_para3:'||p_para3);  
end;  
 
SQL> var p1 varchar2(10);  
SQL> var p2 varchar2(10);  
SQL> var p3 varchar2(10);  
SQL> exec :p1 :='aaaa';  
SQL> exec :p2 :='bbbb';  
SQL> exec :p3 :='cccc';  
SQL> exec proc1(:p1,:p2,:p3);  
p_para1:aaaa  
p_para2:  
p_para3:張三豐  
SQL> exec dbms_output.put_line(:p2);  
 
 
PL/SQL procedure successfully completed  
p2  
--------- 

INOUT 是真正的按引用傳遞參數。即可作為傳入參數也可以作為傳出參數。

1.3 存儲過程參數寬度  

create or replace procedure proc1(  
 p_para1 varchar2,  
 p_para2 out varchar2,  
 p_para3 in out varchar2  
)as  
 v_name varchar2(2);  
begin  
 v_name := p_para1;  
end;  
SQL> var p1 varchar2(10);  
SQL> var p2 varchar2(20);  
SQL> var p3 varchar2(30);  
SQL> exec :p1 :='aaaaaa';  
SQL> exec proc1(:p1,:p2,:p3);  
ORA-06502: PL/SQL: numeric or value error: character string buffer too small  
ORA-06512: at "LIFEMAN.PROC1", line 8 
ORA-06512: at line 1 

首先，我們要明白，我們無法在存儲過程的定義中指定存儲參數的寬度，也就導致了我們無法在存儲過程中控制傳入變量的寬度。

這個寬度是完全由外部傳入時決定的。

我們再來看看OUT類型的參數的寬度。

create or replace procedure proc1(  
 p_para1 varchar2,  
 p_para2 out varchar2,  
 p_para3 in out varchar2  
)as  
 v_name varchar2(2);  
begin  
 p_para2 :='aaaaaaaaaaaaaaaaaaaa';  
end;  
SQL> var p1 varchar2(1);  
SQL> var p2 varchar2(1);  
SQL> var p3 varchar2(1);  
SQL> exec :p2 :='a';  
SQL> exec proc1(:p1,:p2,:p3); 

 在該過程中，p_para2被賦予了20個字符a.

而在外部的調用過程中，p2這個參數僅僅被定義為varchar2(1).

而把p2作為參數調用這個過程，卻並沒有報錯。而且它的真實值就是20個a

SQL> select dump(:p2) from dual;  
DUMP(:P2)  
---------------------------------------------------------------------------  
Typ=1 Len=20: 97,97,97,97,97,97,97,97,97,97,97,97,97,97,97,97,97,97,97,97 
p2  
---------  
aaaaaaaaaaaaaaaaaaaa 

 再來看看IN OUT參數的寬度  

create or replace procedure proc1(  
 p_para1 varchar2,  
 p_para2 out varchar2,  
 p_para3 in out varchar2  
)as  
 v_name varchar2(2);  
begin  
 p_para3 :='aaaaaaaaaaaaaaaaaaaa';  
end;  
SQL> var p1 varchar2(1);  
SQL> var p2 varchar2(1);  
SQL> var p3 varchar2(1);  
SQL> exec proc1(:p1,:p2,:p3); 

執行這個過程，仍然正確執行。

可見，對於IN參數，其寬度是由外部決定。

對於OUT 和IN OUT 參數，其寬度是由存儲過程內部決定。

因此，在寫存儲過程時，對參數的寬度進行說明是非常有必要的，最明智的方法就是參數的數據類型使用%type。這樣雙方就達成了一致。

1.3 參數的默認值

存儲過程的參數可以設置默認值

create or replace procedure procdefault(p1 varchar2,  
                    p2 varchar2 default 'mark')  
as  
begin  
 dbms_output.put_line(p2);  
end;  
SQL> set serveroutput on;  
SQL> exec procdefault('a'); 
mark 

可以通過default 關鍵字為存儲過程的參數指定默認值。在對存儲過程調用時，就可以省略默認值。
需要注意的是：默認值僅僅支持IN傳輸類型的參數。OUT 和 IN OUT不能指定默認值

對於有默認值的參數不是排在最後的情況。

create or replace procedure procdefault2(p1 varchar2 default 'remark',  
                    p2 varchar2 )  
as  
begin  
 dbms_output.put_line(p1);  
end; 

第一個參數有默認值，第二個參數沒有。如果我們想使用第一個參數的默認值時

exec procdefault2('aa'); 

這樣是會報錯的。

那怎麼變呢？可以指定參數的值。

SQL> exec procdefault2(p2 =>'aa'); 
remark 

這樣就OK了，指定aa傳給參數p2

2. 存儲過程內部塊

2.1 內部塊

我們知道了存儲過程的結構，語句塊由begin開始，以end結束。這些塊是可以嵌套。在語句塊中可以嵌套任何以下的塊。

Declare … begin … exception … end;  
create or replace procedure innerBlock(p1 varchar2)  
as  
 o1 varchar2(10) := 'out1';  
begin  
 dbms_output.put_line(o1);  
 declare  
  inner1 varchar2(20);  
 begin  
  inner1 :='inner1';  
  dbms_output.put_line(inner1);  
 
  declare  
   inner2 varchar2(20);  
  begin  
   inner2 := 'inner2';  
   dbms_output.put_line(inner2);  
  end;  
 exception  
  when others then  
   null;  
 end;  
end; 

需要注意變量的作用域。

3.存儲過程的常用技巧

3.1 哪種集合?

我們在使用存儲過程的時候經常需要處理記錄集，也就是多條數據記錄。分為單列多行和多列多行，這些類型都可以稱為集合類型。我們在這裡進行比較這些集合類型，以便於在編程時做出正確的選擇。

索引表,也稱為pl/sql表，不能存儲於數據庫中，元素的個數沒有限制,下標可以為負值。

type t_table is table of varchar2(20) index by binary_integer;  
 v_student t_table; 

varchar2(20)表示存放元素的數據類型，binary_integer表示元素下標的數據類型。

嵌套表，索引表沒有 index by子句就是嵌套表，它可以存放於數據中，元素個數無限，下標從1開始，並且需要初始化

type t_nestTable is table of varchar2(20);  
v_class t_nestTable ; 

僅是這樣聲明是不能使用的，必須對嵌套表進行初始化，對嵌套表進行初始化可以使用它的構造函數

v_class :=t_nestTable('a','b','c');

以上敘述就是本文的全部內容，希望對大家學習oracle存儲過程有所幫助。