第一部分：得到Winamp的窗口
Winamp是一個32位的Windows應用程序。也就是說,我們可以使用32位的Windows編程的一些基礎技術來實現控制Winamp，即使用Windows的消息系統。在你給Winamp發送消息之前，你必須得到Winamp窗口的句柄。這裡有個方法，使用外部應用程序（例如你自己編寫的VB應用）就可以達到要求。
Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Dim hwndWinamp as long
hwndWinamp = FindWindow("Winamp v1.x",vbNullString)
大家可能會注意到一點，為什麼要使用類名"Winamp v1.x"來FindWindow呢？因為Winamp 1.x 和 2.x 的所有版本都是用"Winamp v1.x"這個class name的。
第二部分：使用消息
Winamp相應的三個消息：WM_USER，WM_COMMAND，和 WM_COPYDATA。WM_USER 和 WM_COPYDATA 允許你可以對Winamp進行一些高級的控制。而WM_COMMAND則可以做一些簡單的操作，如暫停，播放，和跳到下一首音樂。
1.WM_COMMAND 消息：
Previous track button 40044
Next track button 40048
Play button 40045
Pause/Unpause button 40046
Stop button 40047
Fadeout and stop 40147
Stop after current track 40157
Fast-forward 5 seconds 40148
Fast-rewind 5 seconds 40144
Start of playlist 40154
Go to end of playlist 40158
Open file dialog 40029
Open URL dialog 40155
Open file info box 40188
Set time display mode to elapsed 40037
Set time display mode to remaining 40038
Toggle preferences screen 40012
Open visualization options 40190
Open visualization plug-in options 40191
Execute current visualization plug-in 40192
Toggle about box 40041
Toggle title Autoscrolling 40189
Toggle always on top 40019
Toggle Windowshade 40064
Toggle Playlist Windowshade 40266
Toggle doublesize mode 40165
Toggle EQ 40036
Toggle playlist editor 40040
Toggle main window visible 40258
Toggle minibrowser 40298
Toggle easymove 40186
Raise volume by 1% 40058
Lower volume by 1% 40059
Toggle repeat 40022
Toggle shuffle 40023
Open jump to time dialog 40193
Open jump to file dialog 40194
Open skin selector 40219
Configure current visualization plug-in 40221
Reload the current skin 40291
Close Winamp 40001
Moves back 10 tracks in playlist 40197
Show the edit bookmarks 40320
Adds current track as a bookmark 40321
Play audio CD 40323
Load a preset from EQ 40253
Save a preset to EQF 40254
Opens load presets dialog 40172
Opens auto-load presets dialog 40173
Load default preset 40174
Opens save preset dialog 40175
Opens auto-load save preset 40176
Opens delete preset dialog 40178
Opens delete an auto load preset dialog 40180
例程：控制Winamp暫停，播放，和跳到下一首音樂
新建一個標准EXE工程，加入一個模塊，在模塊中加入代碼----------
Option Explicit
Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Public Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
Const WM_COMMAND = &H111
Const IPC_WINAMP_NextTrackButton = 40048 '跳到下一首音樂
Const IPC_WINAMP_PlayButton = 40045 '播放
Const IPC_WINAMP_PauseUnpauseButton = 40046 '暫停
Public hwndWinamp As Long 'Winamp的句柄
Public Sub WinampPlay() '播放
SendMessage hwndWinamp, WM_COMMAND, IPC_WINAMP_PlayButton, 0
End Sub
Public Sub WinampPause() '暫停
SendMessage hwndWinamp, WM_COMMAND, IPC_WINAMP_PauseUnpauseButton, 0
End Sub
Public Sub WinampNext() '跳到下一首音樂
SendMessage hwndWinamp, WM_COMMAND, IPC_WINAMP_NextTrackButton, 0
End Sub
在Form中加入的代碼----------
Option Explicit
Private Sub cmdNext_Click()
WinampNext '跳到下一首音樂
End Sub
Private Sub cmdPause_Click()
WinampPause '暫停
End Sub
Private Sub cmdPlay_Click()
WinampPlay '播放
End Sub
Private Sub Form_Load()
hwndWinamp = FindWindow("Winamp v1.x", vbNullString) '得到Winamp的句柄
If hwndWinamp = 0 Then '判斷Winamp是否運行
MsgBox "請啟動Winamp先！"
Unload Me
End If
End Sub
2.WM_USER 消息：
例程：得到Winamp的版本
新建一個標准EXE工程，加入一個模塊，在模塊中加入代碼----------
Option Explicit
Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
'這是VB的API聲明，不會返回正確的結果
'Public Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hwnd As Long, ByVal wMsg As Long, ByVal wParam As Long, lParam As Any) As Long
'這是正確的SendMessage聲明，才能返回版本信息，讀者可以參考一下兩者的不同
Public Declare Function SendMessage Lib "user32" Alias "SendMessageA" (ByVal hWnd As Long, ByVal wMsg As Long, ByVal wParam As Long, ByVal lParam As Long) As Long
Const WM_USER = &H400
Const WA_GETVERSION = 0
Public hwndWinamp As Long 'Winamp的句柄
Function WinampGetVersion() As String
Dim VersionNum As Long
Dim ReturnVersion As String
VersionNum = SendMessage(hwndWinamp, WM_USER, 0, WA_GETVERSION)
If Len(Hex(VersionNum)) > 3 Then
ReturnVersion = Left(Hex(VersionNum), 1) & "."
ReturnVersion = ReturnVersion & Mid(Hex(VersionNum), 2, 1)
ReturnVersion = ReturnVersion & Right$(Hex(VersionNum), Len(Hex(VersionNum)) - 3)
WinampGetVersion = ReturnVersion
Else
WinampGetVersion = "UNKNOWN"
End If
End Function
在Form中加入的代碼----------
Option Explicit
Private Sub Command1_Click()
MsgBox "你的Winamp的版本是：" & WinampGetVersion
End Sub
Private Sub Form_Load()
hwndWinamp = FindWindow("Winamp v1.x", vbNullString) '得到Winamp的句柄
If hwndWinamp = 0 Then '判斷Winamp是否運行
MsgBox "請啟動Winamp先！"
Unload Me
End If
End Sub
3.WM_COPYDATA 消息：
例程：Winamp的運行時刻在播放列表中加入一首Mp3的歌曲
新建一個標准EXE工程，加入一個模塊，在模塊中加入代碼----------
Option Explicit
Public Declare Function FindWindow Lib "user32" Alias "FindWindowA" (ByVal lpClassName As String, ByVal lpWindowName As String) As Long
Private Declare Function lstrcpy Lib "kernel32" Alias "lstrcpyA" (ByVal lpString1 As String, ByVal lpString2 As String) As Long
Private Declare Function CopyDataSendMessage Lib "user32" Alias "SendMessageA" (ByVal WndID As Long, ByVal wMsg As Long, ByVal wParam As Long, ByRef lParam As COPYDATASTRUCT) As Long
Private Type COPYDATASTRUCT
dwData As Long
cbData As Long
lpData As Long
End Type
Const IPC_PLAYFILE = 100
Const WM_COPYDATA = &H4A
Public hwndWinamp As Long
Public Sub WinampAddSong(SongName As String)
Dim CDS As COPYDATASTRUCT
With CDS
.dwData = IPC_PLAYFILE
.cbData = 100
.lpData = lstrcpy(SongName, SongName)
End With
CopyDataSendMessage hwndWinamp, WM_COPYDATA, 0&, CDS
End Sub
在Form中加入的代碼----------
Option Explicit
Private Sub Command1_Click()
WinampAddSong "I:\Mp3\周傑倫-簡單愛.mp3" '加入一首歌
End Sub
Private Sub Form_Load()
hwndWinamp = FindWindow("Winamp v1.x", vbNullString) '得到Winamp的句柄
If hwndWinamp = 0 Then '判斷Winamp是否運行
MsgBox "請啟動Winamp先！"
Unload Me
End If
End Sub
所有例程在 Win2000 + VB6 中調試通過
