簡介
文件上傳是將任意的文件從客戶機發送到服務器的過程。最簡單、最方便的上傳方法是使用支持RFC1867的浏覽器，如微軟的Internet Explorer4.0以上版本，Netscape3.0以上版本，或者帶附件的Internet Explorer3.0。基於浏覽器的文件上傳是通過帶有屬性ENCTYPE="multipart/form-data"的Html form實現的。這個form也必須包含一個或多個<INPUT TYPE=FILE>項，以讓用戶指定要上傳的本地文件。
帶有ENCTYPE="multipart/form-data"屬性的form所發送的數據必須被一個服務器端過程解析，以展開上傳的文件和其他非文件項。在asp環境中，這種任務用編譯好的active server組件能最好的完成，比如Persits軟件公司的ASPUpload
(http://www.persits.com)。
本文所有示例都是建立在你的系統中安裝了AspUpload的基礎上的。可以在這裡下ASPUpload
免費評估版http://www.persits.com/aspupload.html。解壓文件後，將ASPUpload.dll
放在任意目錄中，在MS DOS窗口中執行命令
regsvr32 c:\dir\ASPUpload.dll
開始
我們來創建一個簡單的能上傳3個文件的Html form，和控制上傳的腳本。
這裡是第一個Html文件
Test1.htm:
<Html>
<BODY BGCOLOR="#FFFFFF">
<FORM METHOD="POST" ENCTYPE="multipart/form-data" ACTION="UploadScript1.ASP">
<INPUT TYPE=FILE SIZE=60 NAME="FILE1"><BR>
<INPUT TYPE=FILE SIZE=60 NAME="FILE2"><BR>
<INPUT TYPE=FILE SIZE=60 NAME="FILE3"><BR>
<INPUT TYPE=SUBMIT VALUE="Upload!">
</FORM>
</BODY>
</Html>
每個 <INPUT TYPE=FILE> 項在浏覽器中顯示成為一個帶有"Browse..."按鈕的文本輸入框。如果你沒看見Browse按鈕，很有可能說明你的浏覽器不支持文件上傳。
這裡是相應的上傳腳本 UploadScript1.ASP:
<Html>
<BODY>
<%
Set Upload = Server.CreateObject("Persits.Upload.1")
Count = Upload.Save("c:\upload")
%>
<% = Count %> files uploaded.
</BODY>
</Html>
ASP腳本的第一行僅僅創建了一個ASPUpload對象的實例。第二行調用組件的Save方法，它實際上的作用是：它解析從浏覽器發送的東西，計算出有多少個文件正在上傳，並且把他們存在服務器上指定的目錄。目錄名可能以反斜線結束，也可能不是。所有文件將以他們原來的名字存放在目錄中。我們很快將看到如何更改任意或者所有文件的名字。
Save方法返回成功上傳的文件數量。萬一發生錯誤，這個方法將拋棄之。
注意你能夠使用我們的form中任意或者全部三個輸入框。ASPUpload有足夠的智慧判斷出哪些輸入框使用了，哪些沒有。
使用FILES和FORMS集合訪問單個form項
我們看看第二組示例：
Test2.htm
<Html>
<BODY BGCOLOR="#FFFFFF">
<FORM METHOD="POST" ENCTYPE="multipart/form-data" ACTION="UploadScript2.ASP">
File 1:<INPUT TYPE=FILE NAME="FILE1">
Description 1:<INPUT TYPE=TEXT NAME="DESCR1"><BR>
File 2:<INPUT TYPE=FILE NAME="FILE2">
Description 2:<INPUT TYPE=TEXT NAME="DESCR2"><BR>
<INPUT TYPE=SUBMIT VALUE="Upload!">
</FORM>
</BODY>
</Html>
UploadScript2.ASP <Html>
<BODY>
<%
Set Upload = Server.CreateObject("Persits.Upload.1")
Upload.Save "c:\upload"
%>
Files:<BR>
<%
For Each File in Upload.Files
Response.Write File.Name & "=" & File.Path & " (" & File.Size & ")<BR>"
Next
%>
<P>
Other items:<BR>
<%
For Each Item in Upload.Form
Response.Write Item.Name & "=" & Item.Value & "<BR>"
Next
%>
</BODY>
</Html>
注意我們的Html form現在有兩種輸入框，TYPE=FILE 和 TYPE=TEXT。因為我們form的ENCTYPE屬性，我們不再能通過標准的ASP Response.Form 集合來訪問form變量。此處Upload.Form 來解決了問題。這個集合實際上和Response.Form一樣，也就是，我們能通過整形或字串型索引訪問它的元素。例如：
Set Item1 = Upload.Form("DESCR1")
或者
Set Item1 = Upload.Form(1).
我們也能夠使用上面示例代碼顯示的For-Each語句遍歷集合中的項。Form集合包含FormItem類型的對象，它只有兩個字串屬性，Name 和 Value (缺省屬性).
記住Upload.Form集合僅僅包含非文件項，也就是不同於<INPUT TYPE=FILE>，這點很重要。ASPUpload提供另外一個集合，叫做Files，來包含UploadedFile類型的對象，這種對象代表已經上傳的來自<INPUT TYPE=FILE>項的文件。很象Form集合，Files集合的項能夠通過使用字串或者整形索引，或者一個For-Each語句訪問，象上面的示例顯示的一樣。
運行示例2以後，我們將看到象這樣的一些東西：
Files:
FILE1=c:\upload\File1.xls (108544)
FILE2=c:\upload\File2.zip (211687)
Other items:
DESCR1=bla bla
DESCR2=test test
注意我們已經通過UploadedFile對象相應的Path和Size屬性獲得了上傳過的文件的目標路徑和文件大小。
如果我們的form只包含一個文件輸入框，<INPUT TYPE=FILE NAME="ONLYFILE">,那麼沒有必要使用For-Each語句。我們只需要這麼說
Response.Write Upload.Files("ONLYFILE").Path
或者,更常用的
Response.Write Upload.Files(1).Path
要點:Files和Form集合在調用Save方法前都不會裝入，因此在調用Upload.Save前就查詢這些集合是不正確的。
' 錯誤!
Upload.Save( Upload.Form("Path") )
限制文件大小
也許你需要限制上傳文件的大小，以防止服務器磁盤空間擁塞。你所需要做的一切就是在調用Save之前在你的Upload對象中調用SetMaxSize:
Set Upload = Server.CreateObject("Persits.Upload.1")
Upload.SetMaxSize 50000, False
Upload.Save "c:\upload"
在這個例子中，我們將上傳文件的大小限制在50000字節內。第二個可選參數指定超出文件最大范圍的部分是否應該被刪除（如果設成false或者不設），或者作為錯誤例外拒絕接收（如果設成True) 。
強制特有文件名
缺省的，ASPUpload將覆蓋上傳路徑中已有的文件。如果你不想這樣，可以配置組件，為上傳文件產生特有的名字來防止覆蓋已有文件。方法是，在調用Save前設置上傳管理器的OverwriteFiles屬性：
Upload.OverwriteFiles = False
缺省值是true。
為防止名字沖突，AspUpload將在原來文件名後面加上用圓括號括起來的整數。例如，如果文件MyFile.txt已經存在於上傳目錄了，並且另外一個同名文件正在上傳，ASPUpload會將新文件存為 MyFile(1).txt。如果我們上傳更多的MyFile.txt，他們將被存MyFile(2).txt, MyFile(3).txt,等等。
移動、拷貝、刪除文件
文件上傳對象提供了一些方法供你移動、拷貝或者刪除上傳的文件。這些方法是
file.Move( NewName As String )
file.Copy( NewLocation As String, Optional Overwrite)
file.Delete
根據NewName參數，Move方法將文件移動到其他目錄或者給他更名。假設文件abc.txt上傳到了目錄
c:\Upload。那麼調用
file.Move "c:\WINNT\abc.txt" 將把文件移動到 c:\WINNT, 而調用
file.Move "c:\Upload\xyz.txt" 只會更改文件名。
要知道Move方法有個副作用是很重要的：當這個方法成功調用後，這個文件對象的Path屬性將指向新目錄/名字。
Copy屬性把文件拷貝到新目錄/名字。新目錄必須是完全合法的路徑。 Overwrite參數如果設成True或者不設，就會指示Copy方法覆蓋新目錄裡的已有文件。 如果設成False，當文件在新目錄中已經存在地時候，會導致方法失敗。與Move方法不同，這個方法不會影響Path屬性。
有時你可能選擇使用Delete方法，例如你在把文件作為BLOBs存入數據庫中，並且不再需要它放在你的上傳路徑裡時。將文件存入數據庫是我們下一個要討論的主題。
把文件作為BLOBs存入數據庫
許多數據庫管理系統象Ms access或者SQL Server將允許你將任意文件存為"binary large objects"(BLOBs)。一個MS Access表格能夠在OLE Object型的數據字段中存放二進制文件。在SQL Server中，相應的數據類型是IMAGE。存放的文件以後能夠重新取出供下載，或者用ADO顯示。
ASPUpload讓你只使用短短一行代碼就能把上傳文件存入數據庫！讓我們看看第三組示例文件。文件 Test3.htm幾乎和Test1.htm相同，因此我們不再把它顯示在這裡。文件UploadScript4.ASP 很值得我們注意：
<Html>
<BODY>
<%
Set Upload = Server.CreateObject("Persits.Upload.1")
Upload.Save "c:\upload"
On Error Resume Next
For Each File in Upload.Files
File.ToDatabase "DSN=data;UID=sa;PWD=xxx;", "insert into Blobs(id, Path, BigBlob) values(12, '" & File.Path & "', ?)"
if Err <> 0 Then
Response.Write "Error saving the file: " & Err.Description
Else
File.Delete
Response.Write "Success!"
End If
Next
%>
</BODY>
</Html>
這一行
On Error Resume Next
指示ASP當以外發生時，不要顯示錯誤信息，只將意外代碼和描述存放到內建的Err對象，並且繼續腳本的執行。
下一行
File.ToDatabase "DSN=data;UID=sa;PWD=xxx;", "insert into Blobs(id, Path, BigBlob) values(12, '" & File.Path & "', ?)"
是將文件存放入數據庫所采用的一切。我們來檢查一下這個方法的兩個參數：
第一個參數是下列格式的ODBC連接字串：
"DSN=datasource;UID=userid;PWD=passWord;<other optional parameters>"
第二個參數是SQL INSERT或者UPDATE語句，帶有一個問號(?)，並且只能帶一個。它的作用是為要存儲的文件提供空間容器。在這個例子中，我們下部的數據庫表Blobs包含三欄：一個Integer ID，一個VARCHAR Path，和一個IMAGE BigBlob。這個SQL INSERT語句將12放入ID欄,文件路徑放入Path欄，真實文件放入BigBlob欄。
下一行檢查語句在成功執行前是否正確。如果成功，Err對象取值0並且刪除文件
（File.Delete行），因為文件已經存入數據庫，不需要再放在上傳路徑中了。否則，Err包含一個數字錯誤代碼，並且Err.Description包含對於意外的語言描述。
將GIF和JPEG圖象存入數據庫很常見。將圖象從數據庫中取出並顯示在Html頁中，你不需要使用任何第三方組件。ADO就能完成任務。
在你的Html頁面中放入普通<IMG>標簽，將SRC屬性指向一個ASP腳本，例如
<IMG SRC="GetImage.ASP?id=4">
GetImage.ASP 腳本看起來可能會是這樣
<%
Set db = Server.CreateObject("ADODB.Connection")
db.Open "data"
Set rs =db.Execute("SELECT BigBlob FROM Blobs where id = " & Request("id") )
Response.ContentType = "image/jpeg" '(or "image/gif")
Response.BinaryWrite rs("BigBlob")
%>
