if exists (select * from dbo.sysobjects where id = object_id(N'[dbo].[p_JobSet]') and OBJECTPROPERTY(id, N'IsProcedure') = 1)
drop procedure [dbo].[p_JobSet]
GO
/*--定時調用存儲過程
創建一個在指定時間,調用指定存儲過程的作業
作業執行完成後會自動刪除*/
/*--調用示例
exec p_JobSet 'master.dbo.xp_cmdshell','2004-1-1 10:30'
--*/
create proc p_JobSet
@prorcname sysname, --要調用定時調用的存儲過程名,如果不在當前庫中,則用:庫名.所有者名.存儲過程名
@job_date datetime --存儲過程的執行時間(包括時間信息)
as
declare @dbname sysname,@jobname sysname
,@date int,@time int
select @jobname='定時發送作業_'+cast(newid() as varchar(36))
,@date=convert(varchar,@job_date,112)
,@time=replace(convert(varchar,@job_date,108),':','')
if exists(select 1 from msdb..sysjobs where name=@jobname)
exec msdb..sp_delete_job @job_name=@jobname
--創建作業
exec msdb..sp_add_job @job_name=@jobname,@delete_level=1
--創建作業步驟
declare @sql varchar(800)
select @sql='exec '+@prorcname
,@dbname=db_name()
exec msdb..sp_add_jobstep @job_name=@jobname,
@step_name = '發送處理步驟',
@subsystem = 'TSQL',
@database_name=@dbname,
@command = @sql,
@retry_attempts = 5, --重試次數
@retry_interval = 5 --重試間隔
--創建調度
EXEC msdb..sp_add_jobschedule @job_name = @jobname,
@name = '時間安排',
@enabled = 1,
@freq_type = 1,
@active_start_date = @date,
@active_start_time = @time
-- 添加目標服務器
EXEC msdb.dbo.sp_add_jobserver
@job_name = @jobname ,
@server_name = N'(local)'
go
