<%
'******************************************************************
'** 本程序名："無限流"分頁程序
'** 作者：Arbiter(AAsx)
'** 版本：Million Level
'**
'** QQ：22222xx
'** Email：[email protected]
'** http://www.imagecity.org/
'******************************************************************
'**
'** 【作者的話】
'**
'** 分頁程序無疑是許多網絡程序功能中一個比較麻煩的東西，事實上現在
'** 為止絕大部分人還是在使用傳統的分頁方法(Rs.PageSize=xx)，而了解
'** 數據庫操作的人都知道，這種傳統方式有個弊端：第一次打開頁面時，
'** 它會預讀所有的記錄集，這當在數據大的時候，這將是致命的，而且接
'** 下來的翻頁速度也會非常慢，很占用資源。對於十萬數量級以上的數據
'** 庫這種傳統分頁方式已經顯得非常無力，更別說百萬級了（根本沒法操
'** 作）。基於這種原因，促使我做了本程序。
'**
'** 【程序功能】
'**
'** 針對大型的數據庫進行分頁操作，理想的可操作的數據記錄量在200萬
'** 以內(Max Level版將無數量限制，且無論數據庫多大，翻頁速度都是
'** 不變)，這是Million Level版分頁程序在賽揚1G、內存512、win2k環
'** 境下的測試數據：
'**
'** SQLserver 2k + 10萬條記錄 + 每頁顯示20條：
'** 平均翻頁速度：45ms
'** SQLserver 2k + 100萬條記錄 + 每頁顯示20條：
'** 平均翻頁速度：350ms
'**
'**
'** 【分頁原理】
'**
'** 本程序不再使用Rs.PageSize的方式分頁，連接數據庫的游標類型
'** 也不是使用conn,1,x，而是conn,0,1，這應是最快的游標類型了，不要
'** 以為這樣會使程序變得復雜，相反，程序非常簡單，如果你看不明白，
'** 應該是我的編程風格你不習慣，而非程序復雜。
'** "無限流"分頁的中心是：每頁只讀出需要顯示的記錄，不再象傳統
'** 分頁程序預讀全部的數據，這正在本程序最大的優點--占用資源少，同
'** 理速度也得到非常大的提升，特別在數據量越大的時候，它的速度優勢
'** 越明顯（100萬記錄才350ms左右）。
'** 當程序執行後，使用CurcorBegin和CurcorEnd記錄顯示的第一條記
'** 錄和最後一條記錄的ID值，作為下一次翻頁的標記，然後利用Top xx取
'** 出需要的數據顯示，同時又再對ID值進行記錄。
'**
'** 【結 言】
'**
'** 本程序為共享版，提供給各程序愛好者研究使用，若要轉載、散播、修
'** 改或作其他用途，請尊重作者的辛勞，注明出處。
'** 如果本程序中有錯漏、非最優化等缺點，請到www.csdn.net的web開發/
'** ASP欄目中發表討論，為了中國軟件事業的發展，請不要固步自封：）
'**
'********************************************************************
Option Explicit
'Response.Flush
Dim BeginTime,EndTime
BeginTime=Timer
Dim conn,SQLstr,Rs,DefRecordNum,CursorBegin,CursorEnd,CurPageNum,hav
DefRecordNum=20
'--------------獲取相關參數----------
If Request("CursorBegin")="" Then CursorBegin=0 Else CursorBegin=Request("CursorBegin")
If Request("CursorEnd")="" Then CursorEnd=0 Else CursorEnd=Request("CursorEnd")
If Request("CurPageNum")<>"" Then
CurPageNum=CLng(Request("CurPageNum"))
If CurPageNum<=0 Then CurPageNum=1
Else
CurPageNum=1
End If
hav=Request("hav")
If hav="" Then hav="next"
'----------------End-----------------
'------------顯示翻頁內容函數--------
Function TurnPageFS(DisPRecordNum)
Dim n
While Not(Rs.Eof) And n<DispRecordNum
n=n+1
Response.Write "<tr>"&_
"<td bgcolor='efefef'>"&Rs(0)&"</td>"&_
"<td bgcolor='efefef'>"&Rs(1)&"</td>"&_
"<td bgcolor='efefef'>"&Rs(2)&"</td>"&_
"<td bgcolor='efefef'>"&Rs(3)&"</td>"&_
"<td bgcolor='efefef'>"&Rs(4)&"</td>"&_
"<td bgcolor='efefef'>"&Rs(5)&"</td>"&_
"</tr>"
If n=1 Then CursorBegin=Rs(0)
If n=DefRecordNum Or Rs.Eof Then CursorEnd=Rs(0)
Rs.MoveNext
Wend
End Function
'-------------連接數據庫-------------
Set conn=Server.CreateObject("Adodb.Connection")
'SQLstr="Provider=Microsoft.Jet.OLEDB.4.0;Data Source="&Server.Mappath("mldata.mdb")
SQLstr="Driver={SQL Server};server=arbiter;uid=arbiter;pwd=123456;database=mldata"
conn.Open SQLstr
'---------統計總記錄數/總頁數---------
'-PS：推薦使用count(ID)，ID為自動編號且索引，否則速度有可能大打折扣
'-PS：此統計是本程序中最耗資源的一部分，如果取消這段程序，速度會快上10倍左右
Dim TotalRecords,TotalPages
SQLstr="Select count(ID) As RecordSum From ABC"
Set Rs=conn.Execute(SQLstr,0,1)
TotalRecords=Rs("RecordSum")
TotalPages=Abs(Int(TotalRecords/DefRecordNum*(-1)))
Rs.Close
Set Rs=Nothing
'--------根據hav選擇相應的SQL字串-----
Select Case(hav)
Case "back"
CursorEnd=CursorBegin
SQLstr="Select Top "&DefRecordNum&"_
ID,Title,FileName,K,ImgSize,NameSon _
From ABC Where ID<"&CursorBegin&_
" And ID In (Select Top "&DefRecordNum_
&" ID From ABC Where ID<"&CursorBegin_
&" Order by ID DESC) Order by ID"
Case "next"
SQLstr="Select Top "&DefRecordNum_
&" ID,Title,FileName,K,ImgSize,NameSon From ABC Where ID>"&CursorEnd&_
" Order by ID"
End Select
Set Rs=conn.Execute(SQLstr,0,1)
%>
<Html>
<head>
<title>"無限流"分頁程序 作者：Arbiter</title>
<meta http-equiv="Content-Type" content="text/Html; charset=gb2312">
<style type="text/CSS">td,br,div,p,body {font-size:12px}</style>
</head>
<body bgcolor="#FFFFFF" leftmargin="0" topmargin="0">
<table width="100%" border="0" cellspacing="0" cellpadding="3" bgcolor="#E2F5FE">
<tr align="center">
<td colspan="2"><%Response.Write CurPageNum&"/"&TotalPages&"頁 總記錄數："&TotalRecords%></td>
<td><a href="mllist.ASP">首頁</a> <a href=Javascript:turnpage('back');>上一頁</a>
<a href=Javascript:turnpage('next');>下一頁</a> </td>
</tr>
</table>
<table width="100%" border="1" cellspacing="0" cellpadding="3" bgcolor="#CCCCCC">
<tr>
<td>ID</td>
<td>Title</td>
<td>FileName</td>
<td>大小</td>
<td>尺寸</td>
<td>類別</td>
</tr>
<%
TurnPageFS(DefRecordNum)
Rs.Close
Set Rs=Nothing
conn.Close
Set conn=Nothing
%>
</table>
<table width="100%" border="0" cellspacing="0" cellpadding="3" bgcolor="#E2F5FE">
<tr align="center">
<td colspan="2"><%Response.Write CurPageNum&"/"&TotalPages&"頁 總記錄數："&TotalRecords%></td>
<td><a href="mllist.ASP">首頁</a> <a href=Javascript:turnpage('back');>上一頁</a>
<a href=Javascript:turnpage('next');>下一頁</a> </td>
</tr>
</table>
<%
EndTime=Timer
Response.Write "<br>程序執行時間："&(EndTime-BeginTime)*1000&"毫秒"
Response.Write " 第一條記錄的ID值(CursorBegin)="&CursorBegin&" "
Response.Write "最後一條記錄的ID值(CursorEnd)="&CursorEnd&"<br><br>"
%>
<script language="Javascript">
function turnpage(func){
var CurPageNum=<%=CurPageNum%>; //取得當前頁碼
var CursorBegin=<%=CursorBegin%>; //取得第一個顯示的記錄的ID值
var CursorEnd=<%=CursorEnd%>; //取得最後一個顯示的記錄的ID值
var TotalPages=<%=TotalPages%>; //取得頁面總數
var BackUrl='mllist.ASP?CurPageNum='+(CurPageNum-1)+'&CursorBegin='+CursorBegin+'&CursorEnd='+CursorEnd+'&hav=back';
var NextUrl='mllist.ASP?CurPageNum='+(CurPageNum+1)+'&CursorBegin='+CursorBegin+'&CursorEnd='+CursorEnd+'&hav=next';
if(CurPageNum<=1 && func=='back'){
location.href='#';
}else if(CurPageNum>=TotalPages && func=='next'){
location.href='#';
}else if(func=='back'){
location.href=BackUrl;
}else if(func='next'){
location.href=NextUrl;
}
}
</script>
</body>
</Html>
Cnbruce的代碼：
分頁樣例：[首頁] [上頁] [下頁] [尾頁] [頁次：4/5頁] [共86篇 20篇/頁] 轉到：_ 頁
以下為公用代碼，必須具備。
<%filepath=request.servervariables("path_info")%>
<%page=1 '設置變量初始值PAGE=1
page=request.querystring("page") 'page值為接受值
rs.PageSize = 20 '每頁顯示記錄數
if Not IsEmpty(trim(Request("Page"))) then '如果PAGE已經初始化...
Page = CInt(Request("Page")) '接收PAGE並化為數字型賦給PAGE變量
if Page > rs.PageCount then '如果接收的頁數大於總頁數
rs.AbsolutePage = rs.PageCount '設置當前顯示頁等於最後頁
elseif Page <= 0 then '如果page小於等於0
Page = 1 '設置PAGE等於第一頁
else
rs.AbsolutePage = Page '如果大於零,顯示當前頁等於接收的頁數
end if
End if
Page = rs.AbsolutePage%>
第一種分頁
<%if rs.pagecount<>1 and rs.pagecount<>0 then%>'首先判斷頁總數不為1和0
<%if page>1 then%>
<%if page<rs.pagecount then %>
[<a Href="<%=filepath%>?Page=<% = 1%>">首頁</a>]
[<a Href="<%=filepath%>?Page=<% = page -1 %>">上一頁</a>]
[<a Href="<%=filepath%>?Page=<% = page + 1%>">下一頁</a>]
[<a Href="<%=filepath%>?Page=<% = rs.PageCount%>">尾頁</a>]
<%else%>
[<a Href="<%=filepath%>?Page=<% = 1%>">首頁</a>]
[<a Href="<%=filepath%>?Page=<% = page -1 %>">上一頁</a>]
[下一頁] [尾頁]
<% end if %>
<%else%>
[首頁] [上一頁]
[<a Href="<%=filepath%>?Page=<% = page + 1%>">下一頁</a>]
[<a Href="<%=filepath%>?Page=<% = rs.PageCount%>">尾頁</a>]
<%end if %>
<%else%>
[首頁] [上一頁] [下一頁] [尾頁]
<%end if%>
第二種分頁
<%if rs.pagecount<>1 and rs.pagecount<>0 then%>
<%if page>1 then%>
[<a Href="<%=filepath%>?Page=<% = 1%>">首頁</a>]
[<a Href="<%=filepath%>?Page=<% = page -1 %>">上一頁</a>]
<%if page<rs.pagecount then %>
[<a Href="<%=filepath%>?Page=<% = page + 1%>">下一頁</a>]
[<a Href="<%=filepath%>?Page=<% = rs.PageCount%>">尾頁</a>]
<%else%>
[下一頁] [尾頁]
<% end if %>
<%else%>
[首頁] [上一頁]
[<a Href="<%=filepath%>?Page=<% = page + 1%>">下一頁</a>]
[<a Href="<%=filepath%>?Page=<% = rs.PageCount%>">尾頁</a>]
<%end if %>
<%else%>
[首頁] [上一頁] [下一頁] [尾頁]
<%end if%>
第三種
<%if rs.pagecount<>1 and rs.pagecount<>0 then%>
<%if page<rs.pagecount then%>
<%if page=1 then %>
[首頁] [上一頁]
<%else%>
[<a Href="<%=filepath%>?Page=<% = 1%>">首頁</a>]
[<a Href="<%=filepath%>?Page=<% =page -1 %>">上一頁</a>]
<% end if %>
[<a Href="<%=filepath%>?Page=<% = page + 1%>">下一頁</a>]
[<a Href="<%=filepath%>?Page=<% = rs.PageCount%>">尾頁</a>]
<%else%>
[<a Href="<%=filepath%>?Page=<% = 1%>">首頁</a>]
[<a Href="<%=filepath%>?Page=<% =page -1 %>">上一頁</a>]
[下一頁] [尾頁]
<%end if %>
<%else%>
[首頁] [上一頁] [下一頁] [尾頁]
<%end if%>
